使用智能合约实现有许可投票应用

$ goal asset create --creator {ACCOUNT} --total 1000 --unitname votetkn --decimals 0 -d ~/node/data

$ goal asset send -a 0 -f {VOTER_ACCOUNT} -t {VOTER_ACCOUNT}  --creator {CENTRAL_ACCOUNT} --assetid {ASSETID} -d ~/node/data

$ goal asset send -a 1 -f {CENTRAL_ACCOUNT} -t {VOTER_ACCOUNT}  --creator {CENTRAL_ACCOUNT} --assetid {ASSETID} -d ~/node

$ goal app create --creator {CENTRAL_ACCOUNT}   --approval-prog ./p_vote.teal --global-byteslices 1 --global-ints 6 --local-byteslices 1 --local-ints 0 --app-arg "int:1" --app-arg "int:20" --app-arg "int:20" --app-arg "int:100" --clear-prog ./p_vote_opt_out.teal

// Approval Program 审批程序
#pragma version 2

// check if the app is being created 检查是否app被创建
// if so save creator 如果是，保存创建者
int 0
txn ApplicationID
==
bz not_creation

byte "Creator"
txn Sender
app_global_put

// 4 args must be used on creation 创建变量必须使用4个参数
txn NumAppArgs 
int 4
==
bz failed

// set round ranges 设定轮数范围
byte "RegBegin"
txna ApplicationArgs 0
btoi
app_global_put

byte "RegEnd"
txna ApplicationArgs 1
btoi
app_global_put

byte "VoteBegin"
txna ApplicationArgs 2
btoi
app_global_put

byte "VoteEnd"
txna ApplicationArgs 3
btoi
app_global_put

int 1
return

not_creation:

$ goal app optin  --app-id {APPID} --from {ACCOUNT} --app-arg "str:register" -d ~/node/data

// register 注册

txna ApplicationArgs 0
byte "register"
==
bnz register

.
.
.

register:
global Round
byte "RegBegin"
app_global_get
>=

global Round
byte "RegEnd"
app_global_get
<=
&&

int OptIn
txn OnCompletion
==
&&

bz failed
int 1
return

$ goal app call --app-id {APPID} --app-arg "str:vote" --app-arg "str:candidatea" --from {ACCOUNT}  --out=unsignedtransaction1.tx
$ goal asset send --from={ACCOUNT} --to={CENTRAL_ACCOUNT} --creator {CENTRAL_ACCOUNT} --assetid {VOTE_TOKEN_ID} --fee=1000 --amount=1 --out=unsignedtransaction2.tx

$ cat unsignedtransaction1.tx unsignedtransaction2.tx > combinedtransactions.tx
$ goal clerk group -i combinedtransactions.tx -o groupedtransactions.tx 
$ goal clerk sign -i groupedtransactions.tx -o signout.tx
$ goal clerk rawsend -f signout.tx

// vote 投票
txna ApplicationArgs 0
byte "vote" 
==
bnz vote
.
.
.
vote:

// verify in voting rounds 在投票轮中进行验证

global Round
byte "VoteBegin"
app_global_get
>=

global Round
byte "VoteEnd"
app_global_get
<=
&&
bz failed

// Check that the account has opted in 检查账户是否选择
// account offset (0 == sender, 
// 1 == txn.accounts[0], 2 == txn.accounts[1], etc..) 检查账户余额

int 0 
txn ApplicationID
app_opted_in
bz failed

// check if they have the vote token 检查是否有意向资产的投票代币
// assuming assetid 2. This should  2. 应该被更改为合适的资产ID
// be changed to appropriate asset id
// sender
int 0

// hard-coded assetid 硬编码
int 2
// returns frozen asset balance 返回冻结资产余额
// pop frozen 冻结
asset_holding_get AssetBalance
pop

// does voter have at least 1 vote token 判断投票者至少有一个投票代币
int 1
>=
bz failed

// two transactions 两个交易
global GroupSize
int 2
==
bz failed

// second tx is an asset xfer 第二个交易是资产转移
gtxn 1 TypeEnum
int 4
==
bz failed

// creator receiving the vote token 创建者接收投票代币
byte "Creator"
app_global_get
gtxn 1 AssetReceiver
==
bz failed

// verify the proper token spent 验证投票代币消费
gtxn 1 XferAsset 
// hard coded and should be changed  硬编码并应该被修改
int 2
==
bz failed

// spent 1 vote token 消费一个投票代币
gtxn 1 AssetAmount
int 1
==
bz failed

//check local to see if they have voted 检查本地，确认是否进行投票
int 0 // sender 发送者
txn ApplicationID
byte "voted"
app_local_get_ex 

// if voted skip incrementing count 如果投票，跳过
bnz voted
pop

// can only vote for candidate a
// or candidate b 仅能为候选人a或b投票
txna ApplicationArgs 1
byte "candidatea" 
==
txna ApplicationArgs 1
byte "candidateb" 
==
||
bz failed

// read existing vote candidate
// in global state and increment vote 从全局状态或增量投票中读取存在的候选人
int 0
txna ApplicationArgs 1
app_global_get_ex
bnz increment_existing
pop
int 0
increment_existing:
int 1
+
store 1
txna ApplicationArgs 1
load 1
app_global_put

// store the voters choice in local state 在本地状态中存储投票者选择
int 0 //sender
byte "voted"
txna ApplicationArgs 1
app_local_put

int 1
return

voted:
pop
int 1
return